(setq hasMilliSecs (/= (getvar "MILLISECS") nil))
(setvar "LOGFILEMODE" 0)
(vl-load-com)

(if (and (not vle-selectionset->list) (findfile "vle-extension.lsp")) (load "vle-extension.lsp"))

(defun emul-vle-selectionset->list ( ss / lst sslen )
  (if (and ss (setq sslen (sslength ss)))
    (while (>= (setq sslen (1- sslen)) 0)
      (setq lst (cons (ssname ss sslen) lst))
    )
  )
  lst
)

(defun t_vle_selection2list ( count fptr / ss time1 time2 time3 time4 )

  ;;--- build data list
  (setq ss (ssadd))
  (command "_circle" "0,0,0" 10.0)
  (setq ss (ssadd (entlast) ss))
  (command "_line" "0,0,0" "10,10,10" "")
  (setq ss (ssadd (entlast) ss))
  (command "_pline" "0,0" "10,-10" "0,-10" "")
  (setq ss (ssadd (entlast) ss))
  (command "_arc" "0,0" "10,0" "10,10")
  (setq ss (ssadd (entlast) ss))

  ;;--- now run test : NORMAL
  (setq time1 (getvar "MILLISECS"))
  (if (not time1) (setq time1 (getvar "TDUSRTIMER")))
  (if (not time1) (setq time1 0.0))

  (repeat (* count count)
    (emul-vle-selectionset->list ss)
  )

  (setq time2 (getvar "MILLISECS"))
  (if (not time2) (setq time2 (getvar "TDUSRTIMER")))
  (if (not time2) (setq time2 0.0))

  ;;--- now run test : VLE
  (setq time3 (getvar "MILLISECS"))
  (if (not time3) (setq time3 (getvar "TDUSRTIMER")))
  (if (not time3) (setq time3 0.0))

  (repeat (* count count)
    (vle-selectionset->list ss)
  )

  (setq time4 (getvar "MILLISECS"))
  (if (not time4) (setq time4 (getvar "TDUSRTIMER")))
  (if (not time4) (setq time4 0.0))

  ;;--- cleanup
  (command "_erase" "_all" "")
  ;;--- test results
  (setq bench$secsNorm (if hasMilliSecs (* 0.001 (- time2 time1)) (* 86400.0 (- time2 time1))))
  (setq bench$secsFast (if hasMilliSecs (* 0.001 (- time4 time3)) (* 86400.0 (- time4 time3))))
  (setq bench$seconds (+ bench$secsNorm bench$secsFast))

  (princ (strcat "* (Standard) : " (rtos bench$secsNorm 2 3) "  VLE-SELECTIONSET->LIST : " (rtos bench$secsFast 2 3) "\n"))
  (if fptr
    (princ (strcat "* (Standard) : " (rtos bench$secsNorm 2 3) "  VLE-SELECTIONSET->LIST : " (rtos bench$secsFast 2 3) "\n") fptr)
  )

  bench$seconds
)

;; to increase/decrease the number of bench loops : > 1 increase < 1 decrease
(if (not $benchcyclesfactor) (setq $benchcyclesfactor 1))

;; to run this loaded test manually
(defun C:Run ()
  (setvar "cmdecho" 0)
  (print)
  (t_vle_selection2list (* 300 $benchcyclesfactor) nil)
  (setvar "cmdecho" 1)
  (princ)
)
