(setq hasMilliSecs (/= (getvar "MILLISECS") nil))
(setvar "LOGFILEMODE" 0)
(vl-load-com)

(if (and (not vle-vector-get) (findfile "vle-extension.lsp")) (load "vle-extension.lsp"))

(defun emul-vector-get ( fromPt toPt / fromZ toZ )
  (if (or (/= (type fromPt) 'LIST) (not (car fromPt)) (not (cadr fromPt))) (exit))
  (if (or (/= (type toPt)   'LIST) (not (car toPt))   (not (cadr toPt)))   (exit))

  (setq fromZ (caddr fromPt) toZ (caddr toPt))
  (if (not fromZ) (setq fromZ 0.0))
  (if (not toZ)   (setq toZ   0.0))

  (list (- (car toPt) (car fromPt)) (- (cadr toPt) (cadr fromPt)) (- toZ fromZ))
)

(defun t_vle_vector_get ( count fptr / from2d from3d to2d to3d time1 time2 time3 time4 )

  ;;--- build data list
  (setq from2d '(11.0 12.0) from3d '(11.0 12.0 13.0))
  (setq to2d   '(22.0 33.0) to3d   '(22.0 33.0 44.0))

  ;;--- now run test : NORMAL
  (setq time1 (getvar "MILLISECS"))
  (if (not time1) (setq time1 (getvar "TDUSRTIMER")))
  (if (not time1) (setq time1 0.0))

  (repeat (* count count)
    (emul-vector-get from2d to2d)
    (emul-vector-get from2d to3d)
    (emul-vector-get from3d to3d)
  )

  (setq time2 (getvar "MILLISECS"))
  (if (not time2) (setq time2 (getvar "TDUSRTIMER")))
  (if (not time2) (setq time2 0.0))

  ;;--- now run test : VLE
  (setq time3 (getvar "MILLISECS"))
  (if (not time3) (setq time3 (getvar "TDUSRTIMER")))
  (if (not time3) (setq time3 0.0))

  (repeat (* count count)
    (vle-vector-get from2d to2d)
    (vle-vector-get from2d to3d)
    (vle-vector-get from3d to3d)
  )

  (setq time4 (getvar "MILLISECS"))
  (if (not time4) (setq time4 (getvar "TDUSRTIMER")))
  (if (not time4) (setq time4 0.0))

  ;;--- test results
  (setq bench$secsNorm (if hasMilliSecs (* 0.001 (- time2 time1)) (* 86400.0 (- time2 time1))))
  (setq bench$secsFast (if hasMilliSecs (* 0.001 (- time4 time3)) (* 86400.0 (- time4 time3))))
  (setq bench$seconds (+ bench$secsNorm bench$secsFast))

  (princ (strcat "* (Standard) : " (rtos bench$secsNorm 2 3) "  VLE-VECTOR-GET : " (rtos bench$secsFast 2 3) "\n"))
  (if fptr
    (princ (strcat "* (Standard) : " (rtos bench$secsNorm 2 3) "  VLE-VECTOR-GET : " (rtos bench$secsFast 2 3) "\n") fptr)
  )

  bench$seconds
)

;; to increase/decrease the number of bench loops : > 1 increase < 1 decrease
(if (not $benchcyclesfactor) (setq $benchcyclesfactor 1))

;; to run this loaded test manually
(defun C:Run ()
  (setvar "cmdecho" 0)
  (print)
  (t_vle_vector_get (* 300 $benchcyclesfactor) nil)
  (setvar "cmdecho" 1)
  (princ)
)
